lunchLocation = (dayOfTheWeek == "Tuesday") ? "Fuddruckers" : "Food Court";

The conditional ternary operator doesn’t exist out of the box, but it’s pretty easy to create your own function in VBScript:

Function IIf(bClause, sTrue, sFalse)
    If CBool(bClause) Then
        IIf = sTrue
    Else 
        IIf = sFalse
    End If
End Function

You can then use this, as for the example above:

lunchLocation = IIf(dayOfTheWeek = "Tuesday", "Fuddruckers", "Food Court")

The advantage of this over using a single line If/Then/Else is that it can be directly concatenated with other strings. Using If/Then/Else on a single line must be the only statement on that line.

There is no error checking on this, and the function expects a well formed expression that can be evaluated to a boolean passed in as the clause.

It’s also worth noting that unlike a real ternary operator, both the sTrue and sFalse parameters will be evaluated regardless of the value of bClause. This is fine if you use it with strings as in the question, but be very careful if you pass in functions as the second and third parameters!

The post Single line “if” statement in VBScript (like in C# or PHP) first appeared on MaxVergelli.com.

Function ConvertToUnixTimeStamp(input_datetime) 'As String 
  Dim d
  d = CDate(input_datetime) 
  ConvertToUnixTimeStamp = CStr(DateDiff("s", "01/01/1970 00:00:00", d)) 
End Function

Then, to get back the datetime from the Unix timestamp use the following code:

Function ConvertUnixTimeStampToDateTime(input_unix_timestamp) 'As String [regular datetime] 
  ConvertUnixTimeStampToDateTime = CStr(DateAdd("s", input_unix_timestamp, "01/01/1970 00:00:00")) 
End Function

The post Convert a DateTime string to a Unix timestamp in VbScript / Classic ASP first appeared on MaxVergelli.com.

Function Base64Encode(sText)
  Dim oXML, oNode
  Set oXML = CreateObject("Msxml2.DOMDocument.3.0")
  Set oNode = oXML.CreateElement("base64")
  oNode.dataType = "bin.base64"
  oNode.nodeTypedValue = Stream_StringToBinary(sText)
  Base64Encode = oNode.text
  Set oNode = Nothing
  Set oXML = Nothing
End Function

Function Base64Decode(ByVal vCode)
  Dim oXML, oNode
  Set oXML = CreateObject("Msxml2.DOMDocument.3.0")
  Set oNode = oXML.CreateElement("base64")
  oNode.dataType = "bin.base64"
  oNode.text = vCode
  Base64Decode = Stream_BinaryToString(oNode.nodeTypedValue)
  Set oNode = Nothing
  Set oXML = Nothing
End Function

Private Function Stream_StringToBinary(Text)
  Const adTypeText = 2
  Const adTypeBinary = 1
  Dim BinaryStream 'As New Stream
  Set BinaryStream = CreateObject("ADODB.Stream")
  BinaryStream.Type = adTypeText
  BinaryStream.CharSet = "us-ascii"
  BinaryStream.Open
  BinaryStream.WriteText Text
  BinaryStream.Position = 0
  BinaryStream.Type = adTypeBinary
  BinaryStream.Position = 0
  Stream_StringToBinary = BinaryStream.Read
  Set BinaryStream = Nothing
End Function

Private Function Stream_BinaryToString(Binary)
  Const adTypeText = 2
  Const adTypeBinary = 1
  Dim BinaryStream 'As New Stream
  Set BinaryStream = CreateObject("ADODB.Stream")
  BinaryStream.Type = adTypeBinary
  BinaryStream.Open
  BinaryStream.Write Binary
  BinaryStream.Position = 0
  BinaryStream.Type = adTypeText
  BinaryStream.CharSet = "us-ascii"
  Stream_BinaryToString = BinaryStream.ReadText
  Set BinaryStream = Nothing
End Function

The post Base64 encoding / decoding functions in VbScript / Classic ASP first appeared on MaxVergelli.com.

[sourcecode language=”vb”]
<!–#include file="AssociativeArrayClass.asp" –>
<%
Dim Person, God
Set Person = New AssociativeArray
Set God = New AssociativeArray
Person("name") = "Max"
Person("surname") = "Vergelli"
God("name") = "Jesus"
God("surname") = "Christ"
Dim World
Set World = New AssociativeArray
World(1) = Person
World(2) = God
response.Write World.ToXML()
%>
[/sourcecode]

And You will get out the following XML:

[sourcecode language=”xml”]
<?xml version="1.0" encoding="utf-8"?>
<array>
<key>
<name><![CDATA[1]]></name>
<value>
<key>
<name><![CDATA[name]]></name>
<value><![CDATA[Max]]></value>
</key>
<key>
<name><![CDATA[surname]]></name>
<value><![CDATA[Vergelli]]></value>
</key>
</value>
</key>
<key>
<name><![CDATA[2]]></name>
<value>
<key>
<name><![CDATA[name]]></name>
<value><![CDATA[Jesus]]></value>
</key>
<key>
<name><![CDATA[surname]]></name>
<value><![CDATA[Christ]]></value>
</key>
</value>
</key>
</array>
[/sourcecode]

The post How to export an ASP Associative Array to XML first appeared on MaxVergelli.com.

Before to start:
For this tutorial, You need to download this MS Access database example or You can create a new one in MySQL executing this SQL:

[sourcecode language=”sql”]
CREATE TABLE `myTable` (
`myField1` INT( 11 ) NOT NULL ,
`myField2` VARCHAR( 255 ) NULL DEFAULT ‘test’,
`myField3` VARCHAR( 255 ) NULL DEFAULT ‘test’,
PRIMARY KEY ( `myField1` )
) TYPE = MYISAM ;
INSERT INTO `myTable` (`myField1`, `myField2`, `myField3`)
 VALUES(1, ‘rec1 Text2’, ‘rec1 Text3’);
INSERT INTO `myTable` (`myField1`, `myField2`, `myField3`)
 VALUES(2, ‘rec2 Text2’, ‘rec2 Text3’);
INSERT INTO `myTable` (`myField1`, `myField2`, `myField3`)
 VALUES(3, ‘rec3 Text2’, ‘rec3 Text3’);
[/sourcecode]

Besides, to create an “AssociativeArray” object, You need to include the “ASP Associative Array Class” file in your asp page with an include statement:

[sourcecode language=”vb”]
<!–#include file="AssociativeArrayClass.asp" –>
[/sourcecode]

Tutorial:
The target is to grab data from a database Table and save records in an Associative Array, then You need to create a Database connection by ADODB…

[sourcecode language=”vb”]Set DbConnection = Server.CreateObject("ADODB.Connection")[/sourcecode]

Select a Provider for MS Access or MySQL:

[sourcecode language=”vb”]dbConnectionString = _
   "driver={Microsoft Access Driver (*.mdb)}; DBQ=" & _
           Server.MapPath("myDatabase.mdb")[/sourcecode]

For MySQL Databases You can also use a connection string like the following:

[sourcecode language=”vb”]"driver={MySQL ODBC 3.51 Driver}; Server=; Uid=; Pwd=; Database=;"[/sourcecode]

Open a database connection and create a SQL Select:

[sourcecode language=”vb”]DbConnection.Open dbConnectionString
Dim sql : sql = "SELECT * FROM myTable"[/sourcecode]

Create and Populate the Associative Array with selected Records and close database connection:

[sourcecode language=”vb”]Dim Table
Set Table = New AssociativeArray
Table.Fill DbConnection, sql
Set DbConnection = Nothing[/sourcecode]

Manage Records inside the Associative Array:
Right now, You can manage each record (and its values) inside the Associative Array. For example, You could get the first Record and its Values in each Field:

[sourcecode language=”vb”]Response.Write( _
                Table(0)("myField1") & " , " & _
                Table(0)("myField2") & " , " & _
                Table(0)("myField3") & "<br />")[/sourcecode]

the following code gets the second Record and its Values in each Field:

[sourcecode language=”vb”]Response.Write( _
                Table(1)("myField1") & " , " & _
                Table(1)("myField2") & " , " & _
                Table(1)("myField3") & "<br />")[/sourcecode]

it gets the total Records Count

[sourcecode language=”vb”]Response.Write("<p>Total Records: " & Table.Count & "</p>")[/sourcecode]

this enumerates all Records inside the Associative Array:

[sourcecode language=”vb”]Response.Write("<ul>")
For Each row In Table.Items
   Dim record
   Set record = row.Value ‘get current Record Object
   Response.Write("<li>" & record("myField1") & " : " & _
                           record("myField2") & " : " & _
                           record("myField3") & "</li>")
Next
Response.Write("</ul>")[/sourcecode]

and finally it gets all records by index (zero-based):

[sourcecode language=”vb”]Response.Write("<ul>")
For n = 0 To Table.Count – 1
     Response.Write("<li>" & Table(n)("myField1") & " : " & _
                             Table(n)("myField2") & " : " & _
                             Table(n)("myField3") & "</li>")
Next
Response.Write("</ul>")[/sourcecode]

That’s all,
Get the full example at http://sourceforge.net/projects/asp-assoc-array/

Max

The post How to populate an ASP Associative Array with records from MySQL / Access database Table first appeared on MaxVergelli.com.

Right now, You can start declaring associative arrays in ASP with the following syntax:

[sourcecode language=”vb”]
Dim Person
Set Person = New AssociativeArray
Person("name") = "Max"
Person("surname") = "Vergelli"
Response.Write Person("name") & " " & Person("surname")
[/sourcecode]

In the above example, the key “name” in “Person” object, stores “Max” value. You can set strings or integers for the key and any object/variant type for the relative value. However, You can not set key with Null or “” strings like the following:

[sourcecode language=”vb”]
‘invalid keys…
Person(Null) = "Null Key"
Person("") = "Empty String"
Dim undefined
Person(undefined) = "Variable Not Initialized"
Response.Write Person("") & Person(Null) & Person(undefined)
[/sourcecode]

How to get every item of the associative array:
You can make a “For Each” loop on the array like in the following code

[sourcecode language=”vb”]
For Each element In Person.Items
   Response.Write element.Key & " : " & element.Value & vbCrLf
Next
[/sourcecode]

“Person.Items” gets all the items inside the associative array and for each item You can get “Key” and “Value” properties.

How to copy an associative array:

[sourcecode language=”vb”]
Dim Person_Clone             ‘it’s a Variant type
Set Person_Clone = Person    ‘NOTE: Use "Set" statement!
‘print values
Response.Write Person_Clone("name") & " " & Person_Clone("surname") & vbCrLf
‘get each key/value
For Each element In Person_Clone.Items
   Response.Write element.Key & " : " & element.Value & vbCrLf
Next
[/sourcecode]

How to create nested associative arrays…
You can create infinite nested associative arrays and accessing them like the following:

[sourcecode language=”vb”]
Dim Person
Set Person = New AssociativeArray
Person("name") = "Max"
Person("surname") = "Vergelli"
Dim People
Set People = New AssociativeArray
People(1) = Person
People(2) = Person
People(3) = Person
Response.Write People(1)("name") & " " & People(1)("surname")
[/sourcecode]

Besides, You can enumerate all the keys/values inside the “People” associative array object

[sourcecode language=”vb”]
For Each element In People.Items
   Dim el_person
   Set el_person = element.Value
   Response.Write el_person("name") & " : " & el_person("surname") & vbCrLf
Next
[/sourcecode]

The post How to use Associative Arrays in ASP first appeared on MaxVergelli.com.

It is possible also load in an associative-array the data coming from MySQL or MS Access databases, then You can programmatically manage the structured data; You can also export associative arrays to XML.

Associative arrays are usefull when it is necessary manage many variables at once (for example when we pass multiple values at once to a method/function) or just to store data in a well structured array and reusing  its values anytime.

The post VBScript Class to create easly Associative Arrays in ASP like in PHP first appeared on MaxVergelli.com.